// SPDX-License-Identifier: GPL-3.0-or-later

/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
*
* Copyright (C) 2013 - 2024, nymea GmbH
* Copyright (C) 2024 - 2025, chargebyte austria GmbH
*
* This file is part of nymea-app.
*
* nymea-app is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* nymea-app is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with nymea-app. If not, see <https://www.gnu.org/licenses/>.
*
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */

import QtQuick
import QtQuick.Controls
import QtQuick.Controls.Material
import QtQuick.Layouts

import Nymea

import "../components"

Page {
    id: root
    header: NymeaHeader {
        text: qsTr("System update")
        backButtonVisible: true
        onBackPressed: pageStack.pop()

        HeaderButton {
            text: qsTr("Settings")
            imageSource: "qrc:/icons/settings.svg"
            onClicked: {
                pageStack.push(repositoryListComponent)
            }
        }
    }

    Connections {
        target: engine.systemController
        function onEnableRepositoryFinished(id, success) {
                                        if (!success) {
                                            var popup = errorDialogComponent.createObject(app, {errorCode: qsTr("Failure adding repository.") })
                                            popup.open();
                                        }
                                    }
    }

    PackagesFilterModel {
        id: updatesModel
        packages: engine.systemController.packages
        updatesOnly: true
    }

    Loader {
        id: updateTypeLoader
        anchors.fill: parent
        sourceComponent: engine.systemController.updateManagementType === SystemController.UpdateTypeSystem ?
                             updateSystemComponent :
                             updatePackageManagerComponent

    }

    Component {
        id: updateSystemComponent

        ColumnLayout {
            id: systemUpdateContentColumn

            property Package systemPackage: engine.systemController.packages.get(0)
            property bool changelogAvailable: systemUpdateContentColumn.systemPackage.changelog.length !== 0

            anchors.fill: parent
            anchors.margins: app.margins

            Item {
                Layout.fillHeight: true
                Layout.fillWidth: true
                visible: updatesModel.count === 0

                ColumnLayout {
                    width: parent.width
                    anchors.centerIn: parent
                    spacing: app.margins * 2

                    ColorIcon {
                        Layout.preferredHeight: Style.iconSize * 4
                        Layout.preferredWidth: height
                        Layout.alignment: Qt.AlignHCenter
                        name: "qrc:/icons/system-update.svg"
                        color: Style.accentColor
                        RotationAnimation on rotation {
                            from: 0; to: 360
                            duration: 2000
                            running: engine.systemController.updateManagementBusy
                            loops: Animation.Infinite
                        }
                    }

                    Label {
                        Layout.fillWidth: true
                        Layout.leftMargin: Style.margins
                        Layout.rightMargin: Style.margins

                        wrapMode: Text.WordWrap
                        horizontalAlignment: Text.AlignHCenter
                        text: engine.systemController.updateManagementBusy ? qsTr("Checking for updates...") : qsTr("Your system is up to date.")
                    }

                    Label {
                        id: versionLabel
                        Layout.alignment: Qt.AlignHCenter
                        wrapMode: Text.WordWrap
                        text: qsTr("Version:") + " " + systemUpdateContentColumn.systemPackage.installedVersion

                        MouseArea {
                            anchors.fill: parent
                            onClicked: {
                                PlatformHelper.toClipBoard(versionLabel.text);
                                ToolTip.show(qsTr("Version copied to clipboard"), 500);
                            }
                        }
                    }

                    Button {
                        Layout.fillWidth: true
                        Layout.leftMargin: Style.margins
                        Layout.rightMargin: Style.margins

                        text: qsTr("Check for updates")
                        enabled: !engine.systemController.updateManagementBusy
                        onClicked: {
                            engine.systemController.checkForUpdates()
                        }
                    }
                }
            }

            ColumnLayout {
                Layout.fillHeight: true
                Layout.fillWidth: true
                visible: updatesModel.count > 0

                RowLayout {
                    Layout.margins: app.margins
                    spacing: app.margins

                    ColorIcon {
                        Layout.preferredHeight: Style.iconSize * 2
                        Layout.preferredWidth: height
                        name: "qrc:/icons/system-update.svg"
                        color: Style.accentColor
                        RotationAnimation on rotation {
                            from: 0; to: 360
                            duration: 2000
                            running: engine.systemController.updateManagementBusy
                            loops: Animation.Infinite
                        }
                    }

                    Label {
                        Layout.fillWidth: true
                        text: engine.systemController.updateManagementBusy ? qsTr("Checking for updates...") : qsTr("%1 update available").arg(Configuration.systemName)
                    }
                }


                Button {
                    Layout.fillWidth: true
                    text: qsTr("Check again")
                    enabled: !engine.systemController.updateManagementBusy
                    onClicked: engine.systemController.checkForUpdates()
                }

                NymeaSwipeDelegate {
                    Layout.fillWidth: true
                    text: qsTr("Installed version:")
                    subText: systemUpdateContentColumn.systemPackage.installedVersion
                    progressive: false
                }

                NymeaSwipeDelegate {
                    Layout.fillWidth: true
                    text: qsTr("Candidate version:")
                    subText: systemUpdateContentColumn.systemPackage.candidateVersion
                    visible: systemUpdateContentColumn.systemPackage.updateAvailable || systemUpdateContentColumn.systemPackage.installedVersion.length === 0
                    progressive: false
                }

                ThinDivider {
                    visible: changelogAvailable
                }

                Label {
                    Layout.fillWidth: true
                    Layout.leftMargin: Style.margins
                    Layout.rightMargin: Style.margins

                    visible: changelogAvailable
                    text: qsTr("Update changelog:")
                }

                Label {
                    Layout.fillWidth: true
                    Layout.leftMargin: Style.margins
                    Layout.rightMargin: Style.margins

                    Layout.alignment: Qt.AlignHCenter
                    wrapMode: Text.WordWrap
                    visible: changelogAvailable
                    text: systemPackage.changelog

                }

                Item {
                    Layout.fillWidth: true
                    Layout.fillHeight: true
                }

                Button {
                    Layout.fillWidth: true
                    //Layout.leftMargin: Style.margins
                    //Layout.rightMargin: Style.margins

                    text: qsTr("Update")
                    visible: updatesModel.count > 0
                    enabled: !engine.systemController.updateManagementBusy
                    onClicked: {
                        var dialog = Qt.createComponent(Qt.resolvedUrl("../components/NymeaDialog.qml"));
                        var text = qsTr("This will start a system update. Note that the update might take several minutes and your %1 system might not be functioning properly during this time and restart during the process.\nDo you want to proceed?").arg(Configuration.systemName)
                        var popup = dialog.createObject(app,
                                                        {
                                                            headerIcon: "qrc:/icons/system-update.svg",
                                                            title: qsTr("System update"),
                                                            text: text,
                                                            standardButtons: Dialog.Ok | Dialog.Cancel
                                                        });
                        popup.open();
                        popup.accepted.connect(function() {
                            engine.systemController.updatePackages()
                        })
                    }
                }
            }
        }
    }


    Component {
        id: updatePackageManagerComponent

        ColumnLayout {
            id: contentColumn
            anchors.fill: parent

            Item {
                Layout.fillHeight: true
                Layout.fillWidth: true
                Layout.leftMargin: Style.margins
                Layout.rightMargin: Style.margins

                visible: updatesModel.count === 0

                ColumnLayout {
                    width: parent.width
                    anchors.centerIn: parent
                    spacing: app.margins * 2

                    ColorIcon {
                        Layout.preferredHeight: Style.iconSize * 4
                        Layout.preferredWidth: height
                        Layout.alignment: Qt.AlignHCenter
                        name: "qrc:/icons/system-update.svg"
                        color: Style.accentColor
                        RotationAnimation on rotation {
                            from: 0; to: 360
                            duration: 2000
                            running: engine.systemController.updateManagementBusy
                            loops: Animation.Infinite
                        }
                    }

                    Label {
                        Layout.fillWidth: true
                        horizontalAlignment: Text.AlignHCenter
                        wrapMode: Text.WordWrap
                        text: engine.systemController.updateManagementBusy ? qsTr("Checking for updates...") : qsTr("Your system is up to date.")
                    }

                    Button {
                        Layout.fillWidth: true
                        text: qsTr("Check for updates")
                        enabled: !engine.systemController.updateManagementBusy
                        onClicked: engine.systemController.checkForUpdates()
                    }
                }
            }

            ColumnLayout {
                Layout.fillHeight: true
                Layout.fillWidth: true
                visible: updatesModel.count > 0

                RowLayout {
                    spacing: Style.margins
                    Layout.leftMargin: Style.margins
                    Layout.rightMargin: Style.margins

                    ColorIcon {
                        Layout.preferredHeight: Style.iconSize * 2
                        Layout.preferredWidth: height
                        name: "qrc:/icons/system-update.svg"
                        color: Style.accentColor
                        RotationAnimation on rotation {
                            from: 0; to: 360
                            duration: 2000
                            running: engine.systemController.updateManagementBusy
                            loops: Animation.Infinite
                        }
                    }

                    ColumnLayout {
                        Label {
                            Layout.fillWidth: true
                            text: engine.systemController.updateManagementBusy ? qsTr("Checking for updates...") : qsTr("%n update(s) available", "", updatesModel.count)
                        }
                        GridLayout {
                            columns: width > 250 ? 2 : 1
                            Button {
                                Layout.fillWidth: true
                                text: qsTr("Check again")
                                enabled: !engine.systemController.updateManagementBusy
                                onClicked: {
                                    engine.systemController.checkForUpdates()
                                }
                            }
                            Button {
                                Layout.fillWidth: true
                                text: qsTr("Update all")
                                visible: updatesModel.count > 0
                                enabled: !engine.systemController.updateManagementBusy
                                onClicked: {
                                    var dialog = Qt.createComponent(Qt.resolvedUrl("../components/NymeaDialog.qml"));
                                    var text = qsTr("This will start a system update. Note that the update might take several minutes and your %1 system might not be functioning properly during this time and restart during the process.\nDo you want to proceed?").arg(Configuration.systemName)
                                    var popup = dialog.createObject(app,
                                                                    {
                                                                        headerIcon: "qrc:/icons/system-update.svg",
                                                                        title: qsTr("System update"),
                                                                        text: text,
                                                                        standardButtons: Dialog.Ok | Dialog.Cancel
                                                                    });
                                    popup.open();
                                    popup.accepted.connect(function() {
                                        engine.systemController.updatePackages()
                                    })
                                }
                            }
                        }
                    }

                }

                ThinDivider {}

                ListView {
                    Layout.fillWidth: true
                    Layout.fillHeight: true
                    visible: count > 0
                    model: updatesModel
                    clip: true
                    delegate: NymeaSwipeDelegate {
                        width: parent.width
                        text: model.displayName
                        subText: model.candidateVersion
                        prominentSubText: false
                        iconName: model.updateAvailable
                                  ? Qt.resolvedUrl("qrc:/icons/system-update.svg")
                                  : Qt.resolvedUrl("qrc:/icons/view-" + (model.installedVersion.length > 0 ? "expand" : "collapse") + ".svg")
                        iconColor: model.updateAvailable
                                   ? "green"
                                   : model.installedVersion.length > 0 ? "blue" : Style.iconColor
                        onClicked: {
                            pageStack.push(Qt.resolvedUrl("PackageDetailsPage.qml"), {pkg: updatesModel.get(index)})
                        }
                    }
                }
            }

            ThinDivider {}

            NymeaSwipeDelegate {
                Layout.fillWidth: true
                text: qsTr("Install or remove software")
                onClicked: {
                    pageStack.push("PackageListPage.qml")
                }
            }
        }
    }

    Component {
        id: repositoryListComponent
        Page {
            id: repositoryListPage
            header: NymeaHeader {
                text: qsTr("Update sources")
                onBackPressed: pageStack.pop()
            }
            ListView {
                anchors.fill: parent
                model: engine.systemController.repositories
                delegate: CheckDelegate {
                    width: parent.width
                    text: model.displayName
                    checked: model.enabled
                    onClicked: {
                        if (checked) {
                            var dialog = Qt.createComponent(Qt.resolvedUrl("../components/NymeaDialog.qml"));
                            var text = qsTr("Enabling additional software sources allows to install unreleased %1 packages.\nThis can potentially break your system and lead to problems.\nPlease only use this if you are sure you want this and consider reporting the issues you find when testing unreleased channels.").arg(Configuration.systemName)
                            var popup = dialog.createObject(app,
                                                            {
                                                                headerIcon: "qrc:/icons/dialog-warning-symbolic.svg",
                                                                title: qsTr("Enable package source"),
                                                                text: text,
                                                                standardButtons: Dialog.Ok | Dialog.Cancel
                                                            });
                            popup.open();
                            popup.accepted.connect(function() {
                                engine.systemController.enableRepository(model.id, true)
                            })
                            popup.rejected.connect(function() {
                                checked = false
                            })
                        } else {
                            engine.systemController.enableRepository(model.id, false)
                        }
                    }
                }
            }
            UpdateRunningOverlay {
            }
        }
    }

    UpdateRunningOverlay { }

    Component {
        id: errorDialogComponent

        ErrorDialog {
            id: errorDialog
        }
    }
}