greaterThan(QT_MAJOR_VERSION, 5) {
    message("Building using Qt6 support")
    CONFIG *= c++17
    QMAKE_LFLAGS *= -std=c++17
    QMAKE_CXXFLAGS *= -std=c++17
} else {
    message("Building using Qt5 support")
    CONFIG *= c++11
    QMAKE_LFLAGS *= -std=c++11
    QMAKE_CXXFLAGS *= -std=c++11
    DEFINES += QT_DISABLE_DEPRECATED_UP_TO=0x050F00
}

contains(CONFIG, nymea_gpio_sysfs) {
    message("Building with legacy sysfs GPIO backend")
    DEFINES += NYMEA_GPIO_USE_SYSFS
} else {
    LIBGPIOD_VERSION = $$system(pkg-config --modversion libgpiod)
    message("Building with libgpiod GPIO backend $${LIBGPIOD_VERSION}")
    contains(LIBGPIOD_VERSION, ^2\\..*) {
        message("Building with libgpiod API V2 support")
        DEFINES += NYMEA_GPIO_LIBGPIOD_V2
    } else {
        message("Building with libgpiod API V1 support")
    }
}

QMAKE_CXXFLAGS += -Werror -g

gcc {
    COMPILER_VERSION = $$system($$QMAKE_CXX " -dumpversion")
    COMPILER_MAJOR_VERSION = $$str_member($$COMPILER_VERSION)
    greaterThan(COMPILER_MAJOR_VERSION, 7): QMAKE_CXXFLAGS += -Wno-deprecated-copy
}

QT -= gui

top_srcdir=$$PWD
top_builddir=$$shadowed($$PWD)

VERSION_STRING=$$system('dpkg-parsechangelog | sed -n -e "s/^Version: //p"')
DEFINES += VERSION_STRING=\\\"$${VERSION_STRING}\\\"