# Default to nymea-energy branding if not specified
equals(BRANDING, "") {
    message(Overlay: No branding specified. Selecting default: $${BRANDING})
    BRANDING=nymea-energy
}

BRANDINGS_DIR = $${OVERLAY_PATH}/brandings
!win32 {
    BRANDINGS = $$system(ls $${BRANDINGS_DIR})
    # Make sure the branding exists
    !contains(BRANDINGS, $${BRANDING}) {
        error(Overlay: Invalid branding name: $${BRANDING} \
                Please use one of the available brandings: \
                $$join(BRANDINGS, ', ', '', ''))
            )
    }
}



include($${BRANDINGS_DIR}/$${BRANDING}/overlay-config.pri)

# Define package dir depending on the branding
OVERLAY_PACKAGE_DIR=$${BRANDINGS_DIR}/$${BRANDING}/packaging

# Enable overlay config depending on the branding
message(Overlay: Available brandings: $$join(BRANDINGS, ', ', '', ''))
message(Overlay: Using overlay branding: $${BRANDING})
message(Overlay: Organisation name: $${ORGANISATION_NAME})
message(Overlay: Application name: $${APPLICATION_NAME})
message(Overlay: App ID: $${PACKAGE_URN})